home *** CD-ROM | disk | FTP | other *** search
/ Libris Britannia 4 / science library(b).zip / science library(b) / HAM_RAD / PROPAGAT / 1004A.ZIP / EMELINK.BAS < prev    next >
BASIC Source File  |  1986-05-23  |  3KB  |  97 lines
  1. 10 REM THIS PROGRAM CALCULATES THE SIGNAL TO NOISE
  2. 20 REM RATIO OF EME SIGNALS, GIVEN THE EQUIPMENT
  3. 30 REM PARAMETERS, FOR THE AVERAGE EARTH-MOON DISTANCE.
  4. 40 REM AT PERIGEE SIGNALS WLL BE 1 DB STRONGER, AT APOGEE 1 DB WEAKER.
  5. 50 REM
  6. 60 REM PROGRAM INPUTS ARE OBVIOUS: NOTE THAT THE
  7. 70 REM RECEIVER SENSITIVITY MAY BE GIVEN AS EITHER
  8. 80 REM NOISE FIGURE [NUMBER <20] OR NOISE TEMP
  9. 90 REM [NUMBER >20]; ANTENNA PARAMETERS ARE EITHER
  10. 100 REM THIS PROGRAM CALCULATES THE SIGNAL TO NOISE
  11. 110 REM RATIO OF EME SIGNALS, GIVEN THE EQUIPMENT
  12. 120 REM PARAMETERS, FOR THE AVERAGE EARTH-MOON DISTANCE.
  13. 130 REM AT PERIGEE SIGNALS WLL BE 1 DB STRONGER, AT APOGEE 1 DB WEAKER.
  14. 140 REM
  15. 150 REM PROGRAM INPUTS ARE OBVIOUS: NOTE THAT THE
  16. 160 REM RECEIVER SENSITIVITY MAY BE GIVEN AS EITHER
  17. 170 REM NOISE FIGURE [NUMBER <20] OR NOISE TEMP
  18. 180 REM [NUMBER >20]; ANTENNA PARAMETERS ARE EITHER
  19. 190 REM DISH DIA IN FEET [ENTERED AS A NUMBER], OR
  20. 200 REM ANTENNA GAIN [ENTERED AS GAIN/100, E.G. 9 DB
  21. 210 REM ENTERED AS .09].
  22. 220 REM
  23. 230 REM
  24. 240 REM WRITTEN BY C.W.SUCKLING G3WDG, 28 FEB 1983
  25. 250 REM
  26. 260 REM GET INPUT DATA
  27. 270 GOSUB 350
  28. 280 GOSUB 370
  29. 290 GOSUB 390
  30. 300 GOSUB 410
  31. 310 GOSUB 430
  32. 320 GOSUB 450
  33. 330 GOSUB 480
  34. 340 REM SUBROUTINES TO GET INPUT DATA
  35. 350 INPUT "SYSTEM NOISE TEMP OR NOISE FIGURE ";N
  36. 360 RETURN
  37. 370 INPUT "RX BANDWIDTH (HZ)                 ";B
  38. 380 RETURN
  39. 390 INPUT "FREQUENCY (MHZ)                   ";F
  40. 400 RETURN
  41. 410 INPUT "ANT 1 DIA (FT) OR GAIN (.DB)      ";D1
  42. 420 RETURN
  43. 430 INPUT "ANT 2 DIA (FT) OR GAIN (.DB)      ";D2
  44. 440 RETURN
  45. 450 INPUT "TX POWER (W)                      ";P
  46. 460 RETURN
  47. 470 REM ANTENNA CALCULATIONS
  48. 480 D=D1: GOSUB 530
  49. 490 G1=G: A1$=D$: A1=A
  50. 500 D=D2: GOSUB 530
  51. 510 G2=G: A2$=D$:A2=A
  52. 520 GOTO 590
  53. 530 IF D<1 THEN GOTO 560
  54. 540 D$="FT":G=(4.3422*LOG(5.094*D*D*F*F))-60: A=D
  55. 550 GOTO 570
  56. 560 D$="DB": G=100*D: A=G
  57. 570 RETURN
  58. 580 REM CONVERT NOISE FIGURE TO NOISE TEMPERATURE
  59. 590 IF N<20 THEN GOTO 620
  60. 600 T=N:N$="K"
  61. 610 GOTO 640
  62. 620 T=290*(EXP(.2303*N)-1):N$="DB"
  63. 630 REM CALCULATE RECEIVER NOISE POWER
  64. 640 R=-228.6+4.3422*LOG(T)+4.3422*LOG(B)
  65. 650 REM CALCULATION OF SIGNAL TO NOISE RATIO
  66. 660 L=-271+8.6844*LOG(1296/F)
  67. 670 REM CALCULATION OF PATH LOSS
  68. 680 S=G1+G2+4.3422*LOG(P)+L-R
  69. 690 S=INT(S*10)/10
  70. 700 REM PRINT OUT RESULTS
  71. 710 PRINT
  72. 720 PRINT "CODE  PARAMETER        CURRENT VALUE"
  73. 730 PRINT
  74. 740 PRINT "1     NOISE TEMP/FIG  ";N;N$
  75. 750 PRINT "2     BANDWIDTH       ";B;"HZ"
  76. 760 PRINT "3     FREQUENCY       ";F;"MHZ"
  77. 770 PRINT "4     ANTENNA 1       ";A1;A1$
  78. 780 PRINT "5     ANTENNA 2       ";A2;A2$
  79. 790 PRINT "6     TX POWER        ";P;"W"
  80. 800 PRINT
  81. 810 PRINT "SIGNAL TO NOISE RATIO ";S;"DB"
  82. 820 PRINT
  83. 830 REM GET FURTHER INSTRUCTIONS
  84. 840 INPUT "NEW PARAM (1 TO 6), RE-RUN (R) OR QUIT (Q)";A$
  85. 850 :
  86. 860 PRINT
  87. 870 IF A$= "Q" THEN STOP
  88. 880 IF A$= "R" THEN GOTO 270
  89. 890 IF A$= "1" THEN GOSUB 350
  90. 900 IF A$= "2" THEN GOSUB 370
  91. 910 IF A$= "3" THEN GOSUB 390
  92. 920 IF A$= "4" THEN GOSUB 410
  93. 930 IF A$= "5" THEN GOSUB 430
  94. 940 IF A$= "6" THEN GOSUB 450
  95. 950 GOTO 480
  96. 960 END
  97.